# CheckCXXSymbolExists

This module provides a command to check whether a C++ symbol exists.

Load this module in a CMake project with:

    include(CheckCXXSymbolExists)

## Commands

This module provides the following command:

check_cxx_symbol_exists

  Checks once whether a symbol exists as a function, variable, or preprocessor macro in C++:

      check_cxx_symbol_exists(<symbol> <headers> <variable>)

  This command checks whether the `<symbol>` is available after including the specified header file(s) `<headers>`, and stores the result in the internal cache variable `<variable>`. Multiple header files can be specified in one argument as a string using a semicolon-separated list.

  If the header files define the symbol as a macro, it is considered available and assumed to work. If the symbol is declared as a function or variable, the check also ensures that it links successfully (i.e., the symbol must exist in a linked library or object file).

  Symbols that are types, enum values, or C++ templates are not recognized. For those, consider using the `CheckTypeSize` or `CheckSourceCompiles` module instead.

  This command is intended to check symbols as they appear in C++. For C symbols, use the `CheckSymbolExists` module instead.

  Note

  This command is unreliable for symbols that are (potentially) overloaded functions. Since there is no reliable way to predict whether a given function in the system environment may be defined as an overloaded function or may be an overloaded function on other systems or will become so in the future, it is generally advised to use the `CheckSourceCompiles` module for checking any function symbol (unless it is certain the checked function is not overloaded on other systems or will not be so in the future).

  Variables Affecting the Check

  The following variables may be set before calling this command to modify the way the check is run:

  `CMAKE_REQUIRED_FLAGS`

    A space-separated string of additional flags to pass to the compiler. A semicolon-separated list will not work. The contents of `CMAKE_<LANG>_FLAGS` and its associated configuration-specific `CMAKE_<LANG>_FLAGS_<CONFIG>` variables are automatically prepended to the compiler command before the contents of this variable.

  `CMAKE_REQUIRED_DEFINITIONS`

    A semicolon-separated list of compiler definitions, each of the form `-DFOO` or `-DFOO=bar`. A definition for the name specified by the result variable argument of the check command is also added automatically.

  `CMAKE_REQUIRED_INCLUDES`

    A semicolon-separated list of header search paths to pass to the compiler. These will be the only header search paths used; the contents of the `INCLUDE_DIRECTORIES` directory property will be ignored.

  `CMAKE_REQUIRED_LINK_OPTIONS`

    Added in version 3.14.

    A semicolon-separated list of options to add to the link command (see `try_compile()` for further details).

  `CMAKE_REQUIRED_LIBRARIES`

    A semicolon-separated list of libraries to add to the link command. These can be the names of system libraries, or they can be Imported Targets (see `try_compile()` for further details).

  `CMAKE_REQUIRED_LINK_DIRECTORIES`

    Added in version 3.31.

    A semicolon-separated list of library search paths to pass to the linker (see `try_compile()` for further details).

  `CMAKE_REQUIRED_QUIET`

    Added in version 3.1.

    If this variable evaluates to a boolean true value, all status messages associated with the check will be suppressed.

## Examples

The following example demonstrates how to check for the presence of a preprocessor macro `SEEK_SET` and the C++ function `std::fopen()` from the `<cstdio>` header using this module:

    include(CheckCXXSymbolExists)

    # Check for macro SEEK_SET
    check_cxx_symbol_exists(SEEK_SET "cstdio" HAVE_SEEK_SET)

    # Check for function std::fopen
    check_cxx_symbol_exists(std::fopen "cstdio" HAVE_STD_FOPEN)

## See Also

- The `CheckSymbolExists` module to check whether a C symbol exists.